Cracksiz IDM Lisans Yenileme

Member
Katılım
4 Nis 2023
Mesajlar
26
CyberzCoin
572

Cracksiz orjinal 30 günlük internet download manager programını sürekli olarak basit bir kod yöntemiyle güncel tutuyoruz.​


Yöntem:

1- Boş bir notepad açın ve içerisine aşağıda vereceğim kodları girin.

Kodlar:

Kod:
@setlocal DisableDelayedExpansion
@echo off


:: For unattended mode, run the script with /u parameter.
:: For silent mode, run the script with /s parameter.






::=========================================================================================================
:    Credits:
::=========================================================================================================

::  IDM trial reset logic is taken from @Dukun Cabul's autoit tool IDM Trial Reset Tool 2020
::  https://www.nsaneforums.com/topic/369465--/?do=findComment&comment=1574121

::  Thanks to @abbodi1406 for the awesome tricks

::  @WindowsAddict - IDM Trial Reset Script

::  Homepage: https://www.nsaneforums.com/topic/371047-discussion-internet-download-manager-fixes/
::            login required

::  Email:    [email protected]

::=========================================================================================================







::========================================================================================================================================

title  IDM Trial Reset Script 0.2
set Unattended=
set Silent=
set _args=
set _elev=
set "_arg1=%~1"
if not defined _arg1 goto :NoProgArgs
set "_args=%~1"
set "_arg2=%~2"
set "_arg3=%~3"
if defined _arg2 set "_args=%~1 %~2"
if defined _arg3 set "_args=%~1 %~2 %~3"
for %%A in (%_args%) do (
if /i "%%A"=="-el" set _elev=1
if /i "%%A"=="/u" set Unattended=1
if /i "%%A"=="/s" set Silent=1& set Unattended=1)
:NoProgArgs
for /f "tokens=6 delims=[]. " %%G in ('ver') do set winbuild=%%G
set "_psc=powershell -nop -ep bypass -c"
set "nul=1>nul 2>nul"
set "ELine=echo: & %_psc% write-host -back Black -fore Red ==== ERROR ==== &echo:"
set line=_____________________________________________________________________________________________________

if defined Silent call :Begin >nul 2>&1 & exit /b

:Begin

::========================================================================================================================================

for %%i in (powershell.exe) do if "%%~$path:i"=="" (
echo: &echo ==== ERROR ==== &echo:
echo Powershell is not installed in the system.
echo Aborting...
goto Done
)

::========================================================================================================================================

if %winbuild% LSS 7600 (
%ELine%
echo Unsupported OS version Detected.
echo Project is supported only for Windows 7/8/8.1/10 and their Server equivalent.
goto Done
)

::========================================================================================================================================

::  Elevate script as admin and pass arguments and preventing loop
::  Thanks to @hearywarlot [ https://forums.mydigitallife.net/threads/.74332/ ] for the VBS method.
::  Thanks to @abbodi1406 for the powershell method and solving special characters issue in file path name.
::  VBS as primary method is used because powershell is very slow to load in older systems, and powershell as fallback method is used
::  because windows script host (vbs) maybe blocked in some systems.

%nul% reg query HKU\S-1-5-19 && (
goto :_Passed
) || (
if defined _elev goto :_E_Admin
)

set "_batf=%~f0"
set "_vbsf=%temp%\admin.vbs"
set _PSarg="""%~f0""" -el
if defined _args set _PSarg="""%~f0""" -el """%_args%"""

setlocal EnableDelayedExpansion

(
echo Set strArg=WScript.Arguments.Named
echo Set strRdlproc = CreateObject^("WScript.Shell"^).Exec^("rundll32 kernel32,Sleep"^)
echo With GetObject^("winmgmts:\\.\root\CIMV2:Win32_Process.Handle='" ^& strRdlproc.ProcessId ^& "'"^)
echo With GetObject^("winmgmts:\\.\root\CIMV2:Win32_Process.Handle='" ^& .ParentProcessId ^& "'"^)
echo If InStr ^(.CommandLine, WScript.ScriptName^) ^<^> 0 Then
echo strLine = Mid^(.CommandLine, InStr^(.CommandLine , "/File:"^) + Len^(strArg^("File"^)^) + 8^)
echo End If
echo End With
echo .Terminate
echo End With
echo CreateObject^("Shell.Application"^).ShellExecute "cmd.exe", "/c " ^& chr^(34^) ^& chr^(34^) ^& strArg^("File"^) ^& chr^(34^) ^& strLine ^& chr^(34^), "", "runas", 1
)>"!_vbsf!"

(%nul% cscript //NoLogo "!_vbsf!" /File:"!_batf!" -el "!_args!") && (
del /f /q "!_vbsf!"
exit /b
) || (
del /f /q "!_vbsf!"
%nul% %_psc% "start cmd.exe -arg '/c \"!_PSarg:'=''!\"' -verb runas" && (
exit /b
) || (
goto :_E_Admin
)
)
exit /b

:_E_Admin
%ELine%
echo This script require administrator privileges.
echo To do so, right click on this script and select 'Run as administrator'.
goto Done

:_Passed

::========================================================================================================================================

::  Fix for the special characters limitation in path name
::  Written by @abbodi1406

set "_work=%~dp0"
if "%_work:~-1%"=="\" set "_work=%_work:~0,-1%"

set "_batf=%~f0"
set "_batp=%_batf:'=''%"

setlocal EnableDelayedExpansion

::========================================================================================================================================

if defined Unattended goto Reset

:MainMenu
cls
title  IDM Trial Reset Script 0.2
mode con: cols=98 lines=30
echo:
echo:
echo:
echo:
echo                   _______________________________________________________________
echo                  ^|                                                               ^|
echo                  ^|                                                               ^|
echo                  ^|      [1] Reset IDM Trial                                      ^|
echo                  ^|      ___________________________________________________      ^|
echo                  ^|                                                               ^|
echo                  ^|      [2] Homepage                                             ^|
echo                  ^|                                                               ^|
echo                  ^|      [3] Exit                                                 ^|
echo                  ^|                                                               ^|
echo                  ^|_______________________________________________________________^|
echo:
choice /C:123 /N /M ">                   Enter Your Choice [1,2,3] : "

if errorlevel 3 exit
if errorlevel 2 goto Homepage
if errorlevel 1 goto Reset

::========================================================================================================================================

:Reset

::  Set buffer height independently of window height
::  https://stackoverflow.com/a/13351373
::  Written by @dbenham (stackoverflow)

mode con: cols=105 lines=30
%nul% %_psc% "&{$H=get-host;$W=$H.ui.rawui;$B=$W.buffersize;$B.height=999;$W.buffersize=$B;}"


reg Query "HKLM\Hardware\Description\System\CentralProcessor\0" | find /i "x86" > nul && set arch=x86|| set arch=x64

::========================================================================================================================================

echo:
echo Deleting registry keys...
echo:

for %%# in (
""HKEY_CURRENT_USER\Software\DownloadManager" "/v" "FName""
""HKEY_CURRENT_USER\Software\DownloadManager" "/v" "LName""
""HKEY_CURRENT_USER\Software\DownloadManager" "/v" "Email""
""HKEY_CURRENT_USER\Software\DownloadManager" "/v" "Serial""
""HKEY_CURRENT_USER\Software\DownloadManager" "/v" "scansk""
""HKEY_CURRENT_USER\Software\DownloadManager" "/v" "tvfrdt""
""HKEY_CURRENT_USER\Software\DownloadManager" "/v" "radxcnt""
""HKEY_CURRENT_USER\Software\DownloadManager" "/v" "LstCheck""
""HKEY_CURRENT_USER\Software\DownloadManager" "/v" "ptrk_scdt""
""HKEY_CURRENT_USER\Software\DownloadManager" "/v" "LastCheckQU""
"HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\Internet Download Manager"
"HKEY_LOCAL_MACHINE\Software\Internet Download Manager"
) do for /f "tokens=* delims=" %%A in ("%%~#") do (
set "reg="%%~A"" &reg query !reg! %nul% && call :Delete_Key
)

if "%arch%"=="x86" (
set "CLSID=HKEY_CURRENT_USER\Software\Classes\CLSID"
) else (
set "CLSID=HKEY_CURRENT_USER\Software\Classes\Wow6432Node\CLSID"
)

set RegData=%SystemRoot%\Temp\RegData.txt
set RegData2=%SystemRoot%\Temp\RegData2.txt

if exist %RegData% del /f /q %RegData% %nul%
if exist %RegData2% del /f /q %RegData2% %nul%

reg query %CLSID% > %RegData%

for /f %%a in (%RegData%) do set "reg=%%a" & call :Scan_Key

if exist %RegData% del /f /q %RegData% %nul%
if exist %RegData2% del /f /q %RegData2% %nul%

::========================================================================================================================================

echo:
echo Adding registry key...
echo:

if "%arch%"=="x64" (
set "reg="HKEY_LOCAL_MACHINE\SOFTWARE\WOW6432Node\Internet Download Manager" /v "AdvIntDriverEnabled2""
) else (
set "reg="HKEY_LOCAL_MACHINE\Software\Internet Download Manager" /v "AdvIntDriverEnabled2""
)

reg add !reg! /t REG_DWORD /d "1" /f %nul%

if [!errorlevel!]==[0] (
set "reg=!reg:"=!"
echo Added - !reg!
) else (
set "reg=!reg:"=!"
powershell write-host 'Failed' -fore '"white"' -back ' "DarkRed"' -NoNewline &echo  - !reg!
)

echo:

::========================================================================================================================================

:Done

echo %line%
echo:
echo:
if defined Unattended (
echo Exiting in 3 seconds...
if %winbuild% LSS 7600 (ping -n 3 127.0.0.1 > nul) else (timeout /t 3)
exit /b
)
echo Press any key to exit...
pause >nul
exit /b

::========================================================================================================================================

:Homepage

cls
echo:
echo:
echo Login required.
echo:
echo:
timeout /t 3

start https://www.nsaneforums.com/topic/371047-discussion-internet-download-manager-fixes/
goto MainMenu

::========================================================================================================================================

:Scan_Key

reg query !reg! 2>nul | find /i "H" 1>nul || (
call :Delete_Key
exit /b
)

for %%# in (
LocalServer32
InprocServer32
InprocHandler32
) do for /f "tokens=* delims=" %%G in ("%%~#") do (
reg query !reg! 2>nul | find /i "%%G" 1>nul && exit /b
)

reg query !reg! 2>nul | find /i "Version" 1>nul && (
for /f "skip=2 tokens=2*" %%a in ('reg query !reg!\Version /ve 2^>nul') do if 1%%b EQU +1%%b (
call :Delete_Key
exit /b
)
)

for %%# in (
MData
Model
scansk
Therad
) do for /f "tokens=* delims=" %%G in ("%%~#") do (
reg query !reg! 2>nul | find /i "%%G" 1>nul && (
call :Delete_Key
exit /b
)
)

reg query !reg! 2>nul | find /i "+" 1>nul && (
call :Delete_Key
exit /b
)

for /f "skip=2 tokens=2*" %%a in ('reg query !reg! /ve 2^>nul') do if 1%%b EQU +1%%b (
reg query !reg! > %RegData2%
set /a counter=0
for /f %%a in (%RegData2%) do set /a counter+=1
if [!counter!]==[2] call :Delete_Key
exit /b
)

exit/b

::========================================================================================================================================

:Delete_Key

reg delete !reg! /f %nul%

if [!errorlevel!]==[0] (
set "reg=!reg:"=!"
echo Deleted - !reg!
) else (
set "reg=!reg:"=!"
powershell write-host 'Failed' -fore '"white"' -back ' "DarkRed"' -NoNewline &echo  - !reg!
)

exit /b

::========================================================================================================================================

2- notepad değiştirip sonuna .cmd yazıyoruz. Örneğin idm lisans yenileme.cmd yapabilirsiniz.​


cmd.png

3- Sağ tıklayıp yönetici olarak çalıştırın keyfinize bakın ;)

 
Üst